اصدقائى الاعزاء كلعام وانتم بخير بمناسبة حلول عيد الاضحى المبارك ....اليوم سأقدم لكم شرح عن كيفية  التقاط الفيديو من كاميرا ويب ويعرض في مربع صورة باستخدام خطوات بسيطة و سهلة للغاية:
 
الخطوة الاولى : قم بانشاء وحدة برمجية ثم ضع التعليمات البرمجية التالية فيها
 

الكود:

Public Const ws_child As Long = &H40000000
Public Const ws_visible As Long = &H10000000
 
Global Const WM_USER = 1024
Global Const wm_cap_driver_connect = WM_USER + 10
Global Const wm_cap_set_preview = WM_USER + 50
Global Const WM_CAP_SET_PREVIEWRATE = WM_USER + 52
Global Const WM_CAP_DRIVER_DISCONNECT As Long = WM_USER + 11
Public Const WM_CAP_DLG_VIDEOFORMAT As Long = WM_USER + 41
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function capCreateCaptureWindow Lib "avicap32.dll" Alias "capCreateCaptureWindowA" (ByVal a As String, ByVal b As Long, ByVal c As Integer, ByVal d As Integer, ByVal e As Integer, ByVal f As Integer, ByVal g As Long, ByVal h As Integer) As Long


 
 
الخطوة الثانية : قم بانشاء نافذة و بها عدد 4 زر أمر  بالاسماء التالية  cmdCapture / cmdClose / cmdexit / cmdVideoFormat و مربع صورة
 
_ فى قسم التصريحات العامة نكتب الكود التالى :
 

الكود:

Dim hwdc As Long
Dim startcap As Boolean


 
 
_ فى زر الامر cmdCapture نكتب الكود التالى :

الكود:

Private Sub cmdCapture_Click()
Dim temp As Long
 
 hwdc = capCreateCaptureWindow("Debasis Das", ws_child Or ws_visible, 0, 0, 320, 240, Picture1.hWnd, 0)
 If (hwdc <> 0) Then
   temp = SendMessage(hwdc, wm_cap_driver_connect, 0, 0)
   temp = SendMessage(hwdc, wm_cap_set_preview, 1, 0)
   temp = SendMessage(hwdc, WM_CAP_SET_PREVIEWRATE, 30, 0)
   startcap = True
   Else
   MsgBox ("No Webcam found")
 End If
End Sub


 
 
_فى زر الامر cmdClose نكتب الكود التالى :

الكود:

Private Sub cmdClose_Click()
Dim temp As Long
If startcap = True Then
temp = SendMessage(hwdc, WM_CAP_DRIVER_DISCONNECT, 0&, 0&)
startcap = False
End If
End Sub


 
 
_ فى زر الامر cmdexit نكتب الكود التالى :

الكود:

Private Sub cmdexit_Click()
Unload Me
End Sub


 
 
_فى زر الامر cmdVideoFormat نكتب الكود التالى :

الكود:

Private Sub cmdVideoFormat_Click()
Dim temp As Long
If startcap = True Then
 temp = SendMessage(hwdc, WM_CAP_DLG_VIDEOFORMAT, 0&, 0&)
End If
End Sub


 
 
وفى النهاية ارجو أن يكون الدرس سهل و مفيد

شكرا لك و شرفنى مرورك أخى الكريم