فى هذا الدرس التعليمى سنتحدث عن كيفية حفظ البيانات والسجلات ADO فى ملف XML من خلال 6 Visual Basic بإستخدام الكائن DOMDocument وذلك على النحو التالى :

_إنشاء مشروع قياسى جديد و إضافة زر امر للنافذة و مربع نص لكتابة أسم و مسار قاعدة البيانات فيه

_فى حدث النقر لزر الامر نقوم بكتابة الاكواد التالية

1_بداية وفى حدث النقر لزر الامر نقوم بالاعلان عن الكائنات اللازمة للاتصال بقاعدة البيانات بالاضافة الى الاعلان عن الكائن DOMDocument و الذى سيستخدم لانشاء ملف xml على النحو التالى :

الكود:

Dim db_name As String
Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim dom_document As DOMDocument
 
    db_name = txtDatabase.Text

2_ نقوم بكتابة الاكواد اللازمة للاتصال بقاعدة البيانات وفتحها على النحو التالى :

الكود:

Set conn = New ADODB.Connection
    conn.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Persist Security Info=False;" & _
        "Data Source=" & db_name
    conn.Open

3_ نقوم بفتح اتصال مع سجلات جدول قاعدة البيانات على النحو التالى :

الكود:

Set rs = conn.Execute("SELECT * FROM Books ORDER BY " & _
        "Title")

4_ نقوم بعد ذلك بحفظ البيانات فى الكائن  DOMDocument ثم بعد ذلك نقوم بإغلاق كائنات الاتصال على النحو التالى :

الكود:

Set dom_document = New DOMDocument
    rs.Save dom_document, adPersistXML

    rs.Close
    conn.Close

5_نقوم بعد ذلك بحفظ البيانات الموجودة فى الكائن DOMDocument فى ملف XML على النحو التالى :

الكود:

db_name = Replace$(db_name, ".mdb", ".xml")
    dom_document.Save db_name
    MsgBox "Now move the XML file to a HTTP site."

و الكود النهائى يكون على النحو التالى :

الكود:

Private Sub cmdMakeXmlFile_Click()
Dim db_name As String
Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim dom_document As DOMDocument

   db_name = txtDatabase.Text

     Set conn = New ADODB.Connection
    conn.ConnectionString = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Persist Security Info=False;" & _
        "Data Source=" & db_name
    conn.Open

    Set rs = conn.Execute("SELECT * FROM Books ORDER BY " & _
        "Title")

    Set dom_document = New DOMDocument
    rs.Save dom_document, adPersistXML

    rs.Close
    conn.Close

     db_name = Replace$(db_name, ".mdb", ".xml")
    dom_document.Save db_name
    MsgBox "Now move the XML file to a HTTP site."
End Sub